vms/recipes/alpine/matchbox.pkr.hcl

#Flavour matchbox
build {
  name = "matchbox"
  description = <<EOF
This builder builds a QEMU image from the base build output. The goal here is to install matchbox
with it's provisionning.
EOF

  source "source.qemu.alpine" {
    output_directory = "${var.output_dir}/${var.version}/provisionned/matchbox"
    vm_name          = "${local.output_name}-${var.version}-matchbox.img"
    iso_url          = "${var.output_dir}/${var.version}/base/${local.output_name}-${var.version}.img"
    iso_checksum     = "none"
    disk_size        = 40960
    disk_image       = true
    boot_command     = [ "<enter><enter><wait>" ]
    ssh_clear_authorized_keys = true
  }

  // Install templater and bootstraper
  provisioner "shell" {
    script = "${local.dirs.provisionning}/templater-install.sh"
  }

  // Copy configuration values on the image
  provisioner "shell" {
    inline = [
      "sh -cx 'mkdir -p ${local.builder_config.TemplateDir}'",
      "sh -cx 'mkdir -p ${local.builder_config.ValueDir}'"
    ]
  }

  // Copy configuration templates to the image
  provisioner "file" {
    destination = "${local.builder_config.TemplateDir}/"
    source = "${local.dirs.templates}/conf/${build.name}/"
  }

  // Copy configuration values on the image
  provisioner "file" {
    destination = "${local.builder_config.ValueDir}/${build.name}.json"
    content = "${jsonencode(local.MatchBox)}"
  }

  // Copy matchbox boot provisionning script
  provisioner "file" {
    destination = "/etc/local.d/initmatchbox.start"
    source = "${local.locations.provisionning}/conf/${build.name}/initmatchbox.start"
  }
  
  // Copy tftp provisionning script
  provisioner "file" {
    destination = "/etc/local.d/inittftp.start"
    source = "${local.locations.provisionning}/conf/${build.name}/inittftp.start"
  }

  // Generate default configuration for kubernetes
  provisioner "shell" {
    max_retries = 3
    inline = [ "sh -cx '/usr/local/bin/btr -c ${local.builder_config.ValueDir}/ -t ${local.builder_config.TemplateDir}'" ]
  }

  provisioner "file" {
    destination = "/tmp/${build.name}.sh"
    source      = "${local.dirs.provisionning}/${build.name}.sh"
  }

  provisioner "file" {
    destination = "/tmp/one-context.sh"
    source      = "${local.dirs.provisionning}/one-context.sh"
  }

  provisioner "shell" {
    inline = [
      "sh -cx 'sh /tmp/one-context.sh'",
      "sh -cx 'sh /tmp/${build.name}.sh'"
    ]
  }

  provisioner "file" {
    destination = "/etc/one-context.d/net-96-templater"
    source = "${local.dirs.provisionning}/one-context/net-96-templater"
  }

  provisioner "shell" {
    inline = [ 
      "chmod +x /etc/local.d/initmatchbox.start",
      "chmod +x /etc/local.d/inittftp.start",
      "chmod +x /etc/one-context.d/net-96-templater"
    ]
  }

  post-processor "shell-local" {
    inline = [
      "/bin/sh ${path.cwd}/post-processors/sparsify.sh ${var.output_dir}/${var.version}/provisionned/matchbox ${var.image_version}"
    ]
  }

}