mirror of
https://github.com/puppetmaster/typhoon.git
synced 2024-12-26 04:09:34 +01:00
1caea3388c
* Add an internal `worker` module to the bare-metal module, to
allow individual bare-metal machines to be defined and joined
to an existing bare-metal cluster. This is similar to the "worker
pools" modules for adding sets of nodes to cloud (AWS, GCP, Azure)
clusters, but on metal, each piece of hardware is potentially
unique
New: Using the new `worker` module, a Kubernetes cluster can be defined
without any `workers` (i.e. just a control-plane). Use the `worker`
module to define each piece machine that should join the bare-metal
cluster and customize it in detail. This style is quite flexible and
suited for clusters with hardware that varies quite a bit.
```tf
module "mercury" {
source = "git::https://github.com/poseidon/typhoon//bare-metal/flatcar-linux/kubernetes?ref=v1.26.2"
# bare-metal
cluster_name = "mercury"
matchbox_http_endpoint = "http://matchbox.example.com"
os_channel = "flatcar-stable"
os_version = "2345.3.1"
# configuration
k8s_domain_name = "node1.example.com"
ssh_authorized_key = "ssh-rsa AAAAB3Nz..."
# machines
controllers = [{
name = "node1"
mac = "52:54:00:a1:9c:ae"
domain = "node1.example.com"
}]
}
```
```tf
module "mercury-node1" {
source = "git::https://github.com/poseidon/typhoon//bare-metal/flatcar-linux/kubernetes/worker?ref=v1.26.2"
cluster_name = "mercury"
# bare-metal
matchbox_http_endpoint = "http://matchbox.example.com"
os_channel = "flatcar-stable"
os_version = "2345.3.1"
# configuration
name = "node2"
mac = "52:54:00:b2:2f:86"
domain = "node2.example.com"
kubeconfig = module.mercury.kubeconfig
ssh_authorized_key = "ssh-rsa AAAAB3Nz..."
# optional
snippets = []
node_labels = []
node_tains = []
install_disk = "/dev/vda"
cached_install = false
}
```
For clusters with fairly similar hardware, you may continue to
define `workers` directly within the cluster definition. This
reduces some repetition, but is not quite as flexible.
```tf
module "mercury" {
source = "git::https://github.com/poseidon/typhoon//bare-metal/flatcar-linux/kubernetes?ref=v1.26.1"
# bare-metal
cluster_name = "mercury"
matchbox_http_endpoint = "http://matchbox.example.com"
os_channel = "flatcar-stable"
os_version = "2345.3.1"
# configuration
k8s_domain_name = "node1.example.com"
ssh_authorized_key = "ssh-rsa AAAAB3Nz..."
# machines
controllers = [{
name = "node1"
mac = "52:54:00:a1:9c:ae"
domain = "node1.example.com"
}]
workers = [
{
name = "node2",
mac = "52:54:00:b2:2f:86"
domain = "node2.example.com"
},
{
name = "node3",
mac = "52:54:00:c3:61:77"
domain = "node3.example.com"
}
]
}
```
Optional variables `snippets`, `worker_node_labels`, and
`worker_node_taints` are still defined as a map from machine name
to a list of snippets, labels, or taints respectively to allow some
degree of per-machine customization. However, fields like
`install_disk`, `kernel_args`, `cached_install` and future options
will not be designed this way. Instead, if your machines vary it
is recommended to use the new `worker` module to define each node
88 lines
2.9 KiB
HCL
88 lines
2.9 KiB
HCL
locals {
|
|
# flatcar-stable -> stable channel
|
|
channel = split("-", var.os_channel)[1]
|
|
|
|
remote_kernel = "${var.download_protocol}://${local.channel}.release.flatcar-linux.net/amd64-usr/${var.os_version}/flatcar_production_pxe.vmlinuz"
|
|
remote_initrd = [
|
|
"${var.download_protocol}://${local.channel}.release.flatcar-linux.net/amd64-usr/${var.os_version}/flatcar_production_pxe_image.cpio.gz",
|
|
]
|
|
args = flatten([
|
|
"initrd=flatcar_production_pxe_image.cpio.gz",
|
|
"flatcar.config.url=${var.matchbox_http_endpoint}/ignition?uuid=$${uuid}&mac=$${mac:hexhyp}",
|
|
"flatcar.first_boot=yes",
|
|
var.kernel_args,
|
|
])
|
|
|
|
cached_kernel = "/assets/flatcar/${var.os_version}/flatcar_production_pxe.vmlinuz"
|
|
cached_initrd = [
|
|
"/assets/flatcar/${var.os_version}/flatcar_production_pxe_image.cpio.gz",
|
|
]
|
|
|
|
kernel = var.cached_install ? local.cached_kernel : local.remote_kernel
|
|
initrd = var.cached_install ? local.cached_initrd : local.remote_initrd
|
|
}
|
|
|
|
# Match machine to an install profile by MAC
|
|
resource "matchbox_group" "install" {
|
|
name = format("install-%s", var.name)
|
|
profile = matchbox_profile.install.name
|
|
selector = {
|
|
mac = var.mac
|
|
}
|
|
}
|
|
|
|
// Flatcar Linux install profile (from release.flatcar-linux.net)
|
|
resource "matchbox_profile" "install" {
|
|
name = format("%s-install-%s", var.cluster_name, var.name)
|
|
kernel = local.kernel
|
|
initrd = local.initrd
|
|
args = concat(local.args, var.kernel_args)
|
|
|
|
raw_ignition = data.ct_config.install.rendered
|
|
}
|
|
|
|
# Flatcar Linux install
|
|
data "ct_config" "install" {
|
|
content = templatefile("${path.module}/butane/install.yaml", {
|
|
os_channel = local.channel
|
|
os_version = var.os_version
|
|
ignition_endpoint = format("%s/ignition", var.matchbox_http_endpoint)
|
|
mac = var.mac
|
|
install_disk = var.install_disk
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
# only cached profile adds -b baseurl
|
|
baseurl_flag = var.cached_install ? "-b ${var.matchbox_http_endpoint}/assets/flatcar" : ""
|
|
})
|
|
strict = true
|
|
}
|
|
|
|
# Match a worker to a profile by MAC
|
|
resource "matchbox_group" "worker" {
|
|
name = format("%s-%s", var.cluster_name, var.name)
|
|
profile = matchbox_profile.worker.name
|
|
selector = {
|
|
mac = var.mac
|
|
os = "installed"
|
|
}
|
|
}
|
|
|
|
// Flatcar Linux Worker profile
|
|
resource "matchbox_profile" "worker" {
|
|
name = format("%s-worker-%s", var.cluster_name, var.name)
|
|
raw_ignition = data.ct_config.worker.rendered
|
|
}
|
|
|
|
# Flatcar Linux workers
|
|
data "ct_config" "worker" {
|
|
content = templatefile("${path.module}/butane/worker.yaml", {
|
|
domain_name = var.domain
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
cluster_dns_service_ip = cidrhost(var.service_cidr, 10)
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
node_labels = join(",", var.node_labels)
|
|
node_taints = join(",", var.node_taints)
|
|
})
|
|
strict = true
|
|
snippets = var.snippets
|
|
}
|