Migrate Google Cloud module Terraform v0.11 to v0.12

* Replace v0.11 bracket type hints with Terraform v0.12 list expressions
* Use expression syntax instead of interpolated strings, where suggested
* Update Google Cloud tutorial and worker pools documentation
* Define Terraform and plugin version requirements in versions.tf
  * Require google ~> 2.5 to support Terraform v0.12
  * Require ct ~> 0.3.2 to support Terraform v0.12

google-cloud/container-linux/kubernetes/workers/outputs.tf

@@ -2,12 +2,13 @@
 
 output "instance_group" {
   description = "Worker managed instance group full URL"
-  value       = "${google_compute_region_instance_group_manager.workers.instance_group}"
+  value       = google_compute_region_instance_group_manager.workers.instance_group
 }
 
 # Outputs for regional load balancing
 
 output "target_pool" {
   description = "Worker target pool self link"
-  value       = "${google_compute_target_pool.workers.self_link}"
+  value       = google_compute_target_pool.workers.self_link
 }
+

google-cloud/container-linux/kubernetes/workers/target_pool.tf

@@ -1,11 +1,11 @@
 # Target pool for TCP/UDP load balancing
 resource "google_compute_target_pool" "workers" {
   name             = "${var.name}-worker-pool"
-  region           = "${var.region}"
+  region           = var.region
   session_affinity = "NONE"
 
   health_checks = [
-    "${google_compute_http_health_check.workers.name}",
+    google_compute_http_health_check.workers.name,
   ]
 }
 
@@ -20,3 +20,4 @@ resource "google_compute_http_health_check" "workers" {
   port         = 10254
   request_path = "/healthz"
 }
+

google-cloud/container-linux/kubernetes/workers/variables.tf

@@ -1,53 +1,53 @@
 variable "name" {
-  type        = "string"
+  type        = string
   description = "Unique name for the worker pool"
 }
 
 variable "cluster_name" {
-  type        = "string"
+  type        = string
   description = "Must be set to `cluster_name of cluster`"
 }
 
 # Google Cloud
 
 variable "region" {
-  type        = "string"
+  type        = string
   description = "Must be set to `region` of cluster"
 }
 
 variable "network" {
-  type        = "string"
+  type        = string
   description = "Must be set to `network_name` output by cluster"
 }
 
 # instances
 
 variable "worker_count" {
-  type        = "string"
+  type        = string
   default     = "1"
   description = "Number of worker compute instances the instance group should manage"
 }
 
 variable "machine_type" {
-  type        = "string"
+  type        = string
   default     = "n1-standard-1"
   description = "Machine type for compute instances (e.g. gcloud compute machine-types list)"
 }
 
 variable "os_image" {
-  type        = "string"
+  type        = string
   default     = "coreos-stable"
   description = "Container Linux image for compute instanges (e.g. gcloud compute images list)"
 }
 
 variable "disk_size" {
-  type        = "string"
+  type        = string
   default     = "40"
   description = "Size of the disk in GB"
 }
 
 variable "preemptible" {
-  type        = "string"
+  type        = string
   default     = "false"
   description = "If enabled, Compute Engine will terminate instances randomly within 24 hours"
 }
@@ -55,12 +55,12 @@ variable "preemptible" {
 # configuration
 
 variable "kubeconfig" {
-  type        = "string"
+  type        = string
   description = "Must be set to `kubeconfig` output by cluster"
 }
 
 variable "ssh_authorized_key" {
-  type        = "string"
+  type        = string
   description = "SSH public key for user 'core'"
 }
 
@@ -70,32 +70,34 @@ CIDR IPv4 range to assign Kubernetes services.
 The 1st IP will be reserved for kube_apiserver, the 10th IP will be reserved for coredns.
 EOD
 
-  type    = "string"
+
+  type = string
   default = "10.3.0.0/16"
 }
 
 variable "cluster_domain_suffix" {
   description = "Queries for domains with the suffix will be answered by coredns. Default is cluster.local (e.g. foo.default.svc.cluster.local) "
-  type        = "string"
-  default     = "cluster.local"
+  type = string
+  default = "cluster.local"
 }
 
 variable "clc_snippets" {
-  type        = "list"
+  type = list(string)
   description = "Container Linux Config snippets"
-  default     = []
+  default = []
 }
 
 # unofficial, undocumented, unsupported, temporary
 
 variable "accelerator_type" {
-  type        = "string"
-  default     = ""
+  type = string
+  default = ""
   description = "Google Compute Engine accelerator type (e.g. nvidia-tesla-k80, see gcloud compute accelerator-types list)"
 }
 
 variable "accelerator_count" {
-  type        = "string"
-  default     = "0"
+  type = string
+  default = "0"
   description = "Number of compute engine accelerators"
 }
+

google-cloud/container-linux/kubernetes/workers/versions.tf

@@ -0,0 +1,4 @@
+
+terraform {
+  required_version = ">= 0.12"
+}

google-cloud/container-linux/kubernetes/workers/workers.tf

@@ -5,11 +5,11 @@ resource "google_compute_region_instance_group_manager" "workers" {
 
   # instance name prefix for instances in the group
   base_instance_name = "${var.name}-worker"
-  instance_template  = "${google_compute_instance_template.worker.self_link}"
-  region             = "${var.region}"
+  instance_template  = google_compute_instance_template.worker.self_link
+  region             = var.region
 
-  target_size  = "${var.worker_count}"
-  target_pools = ["${google_compute_target_pool.workers.self_link}"]
+  target_size  = var.worker_count
+  target_pools = [google_compute_target_pool.workers.self_link]
 
   named_port {
     name = "http"
@@ -26,37 +26,38 @@ resource "google_compute_region_instance_group_manager" "workers" {
 resource "google_compute_instance_template" "worker" {
   name_prefix  = "${var.name}-worker-"
   description  = "Worker Instance template"
-  machine_type = "${var.machine_type}"
+  machine_type = var.machine_type
 
   metadata = {
-    user-data = "${data.ct_config.worker-ignition.rendered}"
+    user-data = data.ct_config.worker-ignition.rendered
   }
 
   scheduling {
-    automatic_restart = "${var.preemptible ? false : true}"
-    preemptible       = "${var.preemptible}"
+    automatic_restart = var.preemptible ? false : true
+    preemptible       = var.preemptible
   }
 
   disk {
     auto_delete  = true
     boot         = true
-    source_image = "${var.os_image}"
-    disk_size_gb = "${var.disk_size}"
+    source_image = var.os_image
+    disk_size_gb = var.disk_size
   }
 
   network_interface {
-    network = "${var.network}"
+    network = var.network
 
     # Ephemeral external IP
-    access_config = {}
+    access_config {
+    }
   }
 
   can_ip_forward = true
   tags           = ["worker", "${var.cluster_name}-worker", "${var.name}-worker"]
 
   guest_accelerator {
-    count = "${var.accelerator_count}"
-    type  = "${var.accelerator_type}"
+    count = var.accelerator_count
+    type  = var.accelerator_type
   }
 
   lifecycle {
@@ -67,19 +68,20 @@ resource "google_compute_instance_template" "worker" {
 
 # Worker Ignition config
 data "ct_config" "worker-ignition" {
-  content      = "${data.template_file.worker-config.rendered}"
+  content      = data.template_file.worker-config.rendered
   pretty_print = false
-  snippets     = ["${var.clc_snippets}"]
+  snippets     = var.clc_snippets
 }
 
 # Worker Container Linux config
 data "template_file" "worker-config" {
-  template = "${file("${path.module}/cl/worker.yaml.tmpl")}"
+  template = file("${path.module}/cl/worker.yaml.tmpl")
 
   vars = {
-    kubeconfig             = "${indent(10, var.kubeconfig)}"
-    ssh_authorized_key     = "${var.ssh_authorized_key}"
-    cluster_dns_service_ip = "${cidrhost(var.service_cidr, 10)}"
-    cluster_domain_suffix  = "${var.cluster_domain_suffix}"
+    kubeconfig             = indent(10, var.kubeconfig)
+    ssh_authorized_key     = var.ssh_authorized_key
+    cluster_dns_service_ip = cidrhost(var.service_cidr, 10)
+    cluster_domain_suffix  = var.cluster_domain_suffix
   }
 }
+